EPPClient/build.gradle at main · cubicsrl/EPPClient · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
import com.github.jengelman.gradle.plugins.shadow.tasks.ShadowJar
import java.text.SimpleDateFormat

plugins {
    id 'java'
    id 'application'
    id 'com.github.johnrengelman.shadow' version '8.1.1'
    id("pl.allegro.tech.build.axion-release") version "1.20.1"
}

group = 'com.codetotime'

scmVersion {
    versionCreator('versionWithCommitHash')
}
version = scmVersion.version

tasks.withType(JavaCompile).configureEach {
    options.release = 21
}

repositories {
    mavenCentral()
}

dependencies {
    implementation('org.apache.xmlbeans:xmlbeans:3.1.0')
    implementation('org.apache.httpcomponents:httpclient:4.5.14')
    implementation('org.apache.httpcomponents:httpcore:4.4.16')
    implementation(files('libs/epp-client-cmd-line-1.19.1.jar'))
    implementation('org.apache.derby:derby:10.17.1.0')
    implementation('org.apache.derby:derbytools:10.17.1.0')
    implementation('org.slf4j:slf4j-api:2.0.17')
    implementation('org.slf4j:slf4j-simple:2.0.17')
    implementation('com.google.code.gson:gson:2.13.2')
    implementation('org.mariadb.jdbc:mariadb-java-client:3.5.7')

    testImplementation platform('org.junit:junit-bom:5.10.0')
    testImplementation 'org.junit.jupiter:junit-jupiter'
}

test {
    useJUnitPlatform()
}

application {
    mainClass = 'EPPClient.main'
}

// ShadowJar configuration (fat jar)
tasks.named('shadowJar', ShadowJar) {
    archiveBaseName.set('eppclient')
    manifest {
        attributes('Main-Class': application.mainClass.get())
    }
}
// Generate BuildInfo class
tasks.register('generateBuildInfo') {
    doLast {
        def buildVersion = System.getProperty('buildVersion', project.version.toString())
        def date = new SimpleDateFormat('yyyy-MM-dd').format(new Date())
        def buildCompany = System.getProperty('buildCompany', '')
        def buildPIVA = System.getProperty('buildPIVA', '')
        def buildRegistrarTag = System.getProperty('buildRegistrarTag', '')
        def buildOrder = System.getProperty('buildOrder', '')

        def outputDir = layout.buildDirectory.dir("generated/source/buildinfo").get().asFile
        def buildLabel
        if (!buildCompany.isEmpty() && !buildPIVA.isEmpty()) {
            buildLabel = buildPIVA + ": " + buildCompany
        } else {
            buildLabel = ''
        }

        outputDir.mkdirs()

        def outputFile = file("$outputDir/BuildInfo.java")
        outputFile.text = """package EPPClient;

public class BuildInfo {
    public static final String BUILD_VERSION = "$buildVersion";
    public static final String BUILD_DATE = "$date";
    public static final String BUILD_COMPANY = "$buildCompany";
    public static final String BUILD_PIVA = "$buildPIVA";
    public static final String BUILD_REGISTRAR_TAG = "$buildRegistrarTag";
    public static final String BUILD_ORDER = "$buildOrder";
    public static final String BUILD_LABEL = "$buildLabel";
}
"""
    }
}

compileJava.dependsOn generateBuildInfo

sourceSets {
    main {
        java {
            srcDir "$buildDir/generated/source/buildinfo"
        }
    }
}

jar {
    manifest {
        attributes('Main-Class': application.mainClass)
    }
}