pass strings reference to a function in gdscript

[GianpyRock]

Proposal

Hello, I want to propose to add a keyword for passing strings as a reference into a function call instead of being forced to create a copy of it.

I've encountered a case where I want to decode a string using a parser method and such parser method will be called multiple times with the source string passed unchanged.

But the problem is that the source string is copied each time is passed, it won't change and for me this seem a big waste of process to copy a string just to read it and then trash it away.

Seems to be no feature to do so in current gdscript, the most similar thing is using StringName but for the case I'll describe below this type doesn't seem optimal for it.

Problem

The most obvious solution is that the string must be passed as a reference, but Godot does not have a way to do that with strings.

I should instead pass an object, or an array, that contains the string or define the string as a global variable in the current class.

Or in an extreme case, make bindings with the c++ or c# api to have this feature in the gdscript.

The Feature

Could it be added a new keyword that can pass the string as a reference instead?
It could be ref or reused the existing in keyword to be more similar to c# syntax that implements passing variables by reference.

func _parse(source: ref String) -> void:
  pass

func _parse(source: in String) -> void:
  pass

This seems very obvious that the function is asking for a reference of a string, and not a copy of a string.

• The variable has access to all methods of string.
• The string is not copied, the reference it's.
• The variable cannot be set to null, or at least it won't affect the source.
• The string could be modified, if this feature wants to be "complete" with modifications.
• Maybe other types (such as int) could be added to this feature, in this proposal I'll talk only about string.

My Case

I've encountered this case in my project, the game encodes a level as a string and put it into a text file, each line contains informations I want to decoded composed by words and each word is like a name and a value.

I have my reasons I choose a text file to do this instead of resources or scene file:

• I want to allow modding for this project, and I'm worried that it's possible to put a malevolent script inside a scene. (this is speculation, I haven't checked with the latest version of Godot)
• I don't have full control how much to load from a resource or scene because is loaded whole instead of letting me choose which informations to partially load and which to ignore. This is important for my project idea I don't want to discuss here.

I wrote a function that accepts the string of the line as input, an offset and string length, then decodes the length to extract each word.

I realised that the decode loop will copy the string and I think that's a waste of process that I don't like in my code.

To give full context, this is how the parse loop is structured.

# returns the length of characters from offset to end that are whitespace.
# returns 0 if offset is not a whitespace, otherwise returns how many characters to skip.
static func _decode_whitespace(source: String, offset: int, end: int) -> int:
	var start := offset
	while offset < end:
		var source_char := source.unicode_at(offset)
		if source_char != 0x20 and source_char != 0x0A and source_char != 0x09 and source_char != 0x0D:
			break
		offset += 1
	return offset - start

# returns the length of characters that compose a word.
# words look like this: test, 'test 1'
# returns 0 if no more words or reached end without a word.
static func _decode_word(source: String, offset: int, end: int) -> int:
	var start := offset
	var escaped: bool = false
	var quote_char: int = 0
	while offset < end:
		var source_char := source.unicode_at(offset)
		# breaks if this is a whitespace character and is not part of a quote.
		# SPACE, LINE FEED, CHARACTER TABULATION, CARRIAGE RETURN.
		if quote_char == 0 and (source_char == 0x20 or source_char == 0x0A or source_char == 0x09 or source_char == 0x0D):
			break
		# QUOTATION MARK, APOSTROPHE, GRAVE ACCENT
		elif not escaped and (source_char == 0x22 or source_char == 0x27 or source_char == 0x60):
			# starts quote and ends only with the matching character.
			if quote_char == 0:
				quote_char = source_char
			# terminates quote.
			elif source_char == quote_char:
				quote_char = 0
		# marks the next character to not do any special action and keep it as it is.
		# REVERSE SOLIDUS
		elif source_char == 0x5C:
			escaped = true
		# any generic character.
		else:
			escaped = false
		offset += 1
	return offset - start

# the parse look with an example string, it will iterate 3 times. 1 iteration for each word.
func _ready() -> void:
	var example: String = "word1 'word 2' word3"
	var length := example.length()
	var offset: int = 0
	var lenset: int = 0
	
        # for each iteration the string is copied 2 times!
        # for a large file (+1000 words) it would at least copy the whole string 2000 times.
	while offset != length:
		# skips whitespace.
		offset += _decode_whitespace(example, offset, length)
		# decodes next word length.
		lenset = _decode_word(example, offset, length)
		# extract next word.
		print("\"", example.substr(offset, lenset), "\"")
		# moves cursor for next iteration.
		offset += lenset

---

I think my proposal is valid and I want to share it, I searched and couldn't find about any similar proposal for string reference as I described in this post.

[HolonProduction]

But the problem is that the source string is copied each time is passed, it won't change and for me this seem a big waste of process to copy a string just to read it and then trash it away.

Where are you taking this from, is it based on actual profiling? As far as I'm aware String is internally backed by Copy on Write semantics, so they should only be copied if you make changes.

[GianpyRock]

So... I re-read what I wrote and honestly, I fumbled.

• For some reason I thought CoW means Copy On Reference (???)
• I misunderstand what I was asking for.

That day I saw random memory usage spikes and confused myself while debugging.