Initial CMake bringup

CMakeLists.txt

@@ -0,0 +1,118 @@
+cmake_minimum_required(VERSION 3.20)
+
+if (POLICY CMP0141)
+  cmake_policy(SET CMP0141 NEW)
+  set(CMAKE_MSVC_DEBUG_INFORMATION_FORMAT "$<IF:$<AND:$<C_COMPILER_ID:MSVC>,$<CXX_COMPILER_ID:MSVC>>,$<$<CONFIG:Debug,RelWithDebInfo>:EditAndContinue>,$<$<CONFIG:Debug,RelWithDebInfo>:ProgramDatabase>>")
+endif()
+
+set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_SOURCE_DIR}/cmake/Modules/")
+
+project(openvr_ambient_light)
+
+set(CMAKE_CXX_STANDARD 20)
+set(CMAKE_CXX_STANDARD_REQUIRED ON)
+set(CMAKE_CXX_EXTENSIONS OFF)
+
+set(OpenVR_ROOT ${CMAKE_SOURCE_DIR}/external/openvr)
+find_package(OpenVR REQUIRED)
+
+# Include rest of the CMake bindings
+add_subdirectory(external)
+
+find_program(FXC fxc REQUIRED)
+
+set(SHADER_DIR ${CMAKE_SOURCE_DIR}/shaders)
+set(GEN_DIR    ${CMAKE_BINARY_DIR}/generated/shaders)
+set(BIN_DIR    ${CMAKE_BINARY_DIR}/shader_bin)
+
+file(GLOB_RECURSE HLSL_SHADERS CONFIGURE_DEPENDS
+    ${SHADER_DIR}/*.hlsl
+)
+
+set(GENERATED_HEADERS)
+
+foreach(SHADER ${HLSL_SHADERS})
+
+    file(RELATIVE_PATH REL ${SHADER_DIR} ${SHADER})
+
+    get_filename_component(BASE_NAME ${REL} NAME_WE)
+
+    string(REPLACE "/" "_" BASE_NAME ${BASE_NAME})
+    string(REPLACE "\\" "_" BASE_NAME ${BASE_NAME})
+
+    set(OUT "${GEN_DIR}/${BASE_NAME}.h")
+    set(BIN "${BIN_DIR}/${BASE_NAME}.bin")
+
+    add_custom_command(
+        OUTPUT ${OUT}
+
+        COMMAND ${CMAKE_COMMAND} -E make_directory ${GEN_DIR}
+        COMMAND ${CMAKE_COMMAND} -E make_directory ${BIN_DIR}
+
+        COMMAND ${FXC}
+            -T cs_5_0
+            -E main
+            -Fo ${BIN}
+            ${SHADER}
+
+        COMMAND powershell -ExecutionPolicy Bypass
+            -File ${CMAKE_SOURCE_DIR}/scripts/hlsl2bin.ps1
+            -InputPath  "${BIN}"
+            -OutputPath "${OUT}"
+            -Name       "${BASE_NAME}"
+
+        DEPENDS ${SHADER} ${CMAKE_SOURCE_DIR}/scripts/hlsl2bin.ps1
+        VERBATIM
+    )
+
+    list(APPEND GENERATED_HEADERS ${OUT})
+
+endforeach()
+
+set(SOURCES
+    "src/main.cpp"
+    "src/d3d11_renderer.cpp"
+    "src/settings_menu.cpp"
+    "src/settings_manager.cpp"
+    "src/ambient_light_sampler.cpp"
+    "src/adalight_led_interface.cpp"
+)
+
+add_executable(openvr_ambient_light WIN32 ${SOURCES})
+
+target_sources(openvr_ambient_light PRIVATE ${GENERATED_HEADERS})
+
+target_include_directories(openvr_ambient_light PRIVATE
+    ${CMAKE_BINARY_DIR}/generated
+)
+
+add_custom_target(shader_headers ALL
+    DEPENDS ${GENERATED_HEADERS}
+)
+
+if (UNIX AND NOT APPLE)
+    set_target_properties(openvr_ambient_light PROPERTIES
+        BUILD_RPATH "$ORIGIN"
+        INSTALL_RPATH "$ORIGIN"
+        INSTALL_RPATH_USE_LINK_PATH FALSE
+    )
+endif()
+
+target_include_directories(openvr_ambient_light PUBLIC ${CMAKE_CURRENT_SOURCE_DIR}/include)
+
+# Windows executable icon
+if (WIN32)
+    target_sources(openvr_ambient_light PRIVATE "resources/openvr_ambient_light.rc")
+endif()
+
+target_compile_features(openvr_ambient_light PUBLIC cxx_std_20)
+
+target_link_libraries(openvr_ambient_light
+    PRIVATE
+        OpenVR::API
+        ImGui
+        spdlog_header_only
+        SimpleINI
+        renderdoc
+        d3d11 dxgi dxguid uxtheme pathcch onecore
+)

cmake/Modules/FindOpenVR.cmake

@@ -0,0 +1,96 @@
+# Note: this bitness check does not work for universal builds.
+if (CMAKE_SIZEOF_VOID_P EQUAL 8)
+    set(_openvr_bitness 64)
+else ()
+    set(_openvr_bitness 32)
+endif ()
+
+if (CMAKE_SYSTEM_NAME MATCHES "Darwin")
+    set(_openvr_platform_base osx)
+    set(OpenVR_PLATFORM osx32)
+elseif (CMAKE_SYSTEM_NAME MATCHES "Linux")
+    set(_openvr_platform_base linux)
+    set(OpenVR_PLATFORM "${_openvr_platform_base}${_openvr_bitness}")
+elseif (WIN32)
+    set(_openvr_platform_base win)
+    set(OpenVR_PLATFORM "${_openvr_platform_base}${_openvr_bitness}")
+endif ()
+
+find_path(OpenVR_INCLUDE_DIR
+    NAMES
+        openvr.h
+        openvr_driver.h
+    PATH_SUFFIXES
+        headers)
+mark_as_advanced(OpenVR_INCLUDE_DIR)
+
+set(_openvr_lib_name "")
+if (WIN32)
+    set(_openvr_lib_name openvr_api)
+elseif (CMAKE_SYSTEM_NAME MATCHES "Linux")
+    set(_openvr_lib_name openvr_api)
+elseif (CMAKE_SYSTEM_NAME MATCHES "Darwin")
+    set(_openvr_lib_name openvr_api)
+endif()
+
+find_library(OpenVR_LIBRARY
+    NAMES ${_openvr_lib_name}
+    PATHS ${OpenVR_ROOT}
+    PATH_SUFFIXES "lib/${OpenVR_PLATFORM}")
+mark_as_advanced(OpenVR_LIBRARY)
+
+if (WIN32)
+    find_file(OpenVR_BINARY
+        NAMES openvr_api.dll
+        PATHS ${OpenVR_ROOT}
+        PATH_SUFFIXES "bin/${OpenVR_PLATFORM}")
+    mark_as_advanced(OpenVR_BINARY)
+else()
+    set(OpenVR_BINARY ${OpenVR_LIBRARY})
+endif()
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(OpenVR
+    REQUIRED_VARS OpenVR_LIBRARY OpenVR_INCLUDE_DIR)
+
+if (OpenVR_FOUND)
+    set(OpenVR_INCLUDE_DIRS "${OpenVR_INCLUDE_DIR}")
+    set(OpenVR_LIBRARIES "${OpenVR_LIBRARY}")
+    get_filename_component(OpenVR_LIBRARY_DIR "${OpenVR_LIBRARY}" DIRECTORY)
+
+    if (NOT TARGET OpenVR::API)
+        if (WIN32)
+            add_library(OpenVR::API SHARED IMPORTED)
+            set_target_properties(OpenVR::API
+                PROPERTIES
+                    IMPORTED_IMPLIB "${OpenVR_LIBRARY}"
+                    IMPORTED_LOCATION "${OpenVR_BINARY}"
+                    INTERFACE_INCLUDE_DIRECTORIES "${OpenVR_INCLUDE_DIR}")
+        elseif (CMAKE_SYSTEM_NAME MATCHES "Linux")
+            # Link by name/search path so the executable does not embed an absolute OpenVR path.
+            add_library(OpenVR::API INTERFACE IMPORTED)
+            set_target_properties(OpenVR::API
+                PROPERTIES
+                    INTERFACE_INCLUDE_DIRECTORIES "${OpenVR_INCLUDE_DIR}"
+                    INTERFACE_LINK_DIRECTORIES "${OpenVR_LIBRARY_DIR}"
+                    INTERFACE_LINK_LIBRARIES "openvr_api")
+        else()
+            add_library(OpenVR::API SHARED IMPORTED)
+            set_target_properties(OpenVR::API
+                PROPERTIES
+                    IMPORTED_LOCATION "${OpenVR_LIBRARY}"
+                    INTERFACE_INCLUDE_DIRECTORIES "${OpenVR_INCLUDE_DIR}")
+        endif()
+    endif ()
+
+    if (NOT TARGET OpenVR::Driver)
+        add_library(OpenVR::Driver INTERFACE IMPORTED)
+        set_target_properties(OpenVR::Driver
+            PROPERTIES
+                INTERFACE_INCLUDE_DIRECTORIES "${OpenVR_INCLUDE_DIR}")
+    endif ()
+endif ()
+
+unset(_openvr_bitness)
+unset(_openvr_platform_base)
+unset(_openvr_lib_name)

external/CMakeLists.txt

@@ -0,0 +1,39 @@
+include(${CMAKE_ROOT}/Modules/ExternalProject.cmake)
+
+set(ImGui_ROOT ${CMAKE_SOURCE_DIR}/external/imgui)
+set(ImPlot_ROOT ${CMAKE_SOURCE_DIR}/external/implot)
+set(SimpleINI_ROOT ${CMAKE_SOURCE_DIR}/external/simpleini)
+set(RenderDoc_ROOT ${CMAKE_SOURCE_DIR}/external/renderdoc)
+
+# imgui & implot
+add_library(ImGui STATIC
+    ${ImGui_ROOT}/backends/imgui_impl_dx11.cpp
+	${ImGui_ROOT}/backends/imgui_impl_win32.cpp
+    ${ImGui_ROOT}/imgui.cpp
+	${ImGui_ROOT}/imgui_demo.cpp
+	${ImGui_ROOT}/imgui_draw.cpp
+	${ImGui_ROOT}/imgui_tables.cpp
+	${ImGui_ROOT}/imgui_widgets.cpp
+	${ImGui_ROOT}/misc/cpp/imgui_stdlib.cpp
+	# ImPlot
+	${ImPlot_ROOT}/implot.cpp
+	${ImPlot_ROOT}/implot_items.cpp
+)
+
+target_include_directories(ImGui PUBLIC ${ImGui_ROOT})
+target_include_directories(ImGui PUBLIC ${ImPlot_ROOT})
+
+# spdlog
+add_subdirectory(spdlog)
+
+# simpleini
+add_library(SimpleINI STATIC
+    ${SimpleINI_ROOT}/ConvertUTF.c
+)
+
+target_include_directories(SimpleINI PUBLIC ${SimpleINI_ROOT})
+
+# rederdoc
+add_library(renderdoc INTERFACE)
+
+target_include_directories(renderdoc INTERFACE ${RenderDoc_ROOT})